推荐一个u盘改图标的办法，就是删除后也不怕，快速恢复就行。
主要是使用批处理的方法。
下面介绍步骤：
打开记事本，输入以下内容：
@echo off
color 3f
title ADDico by LitteJack

:menu
cls
echo.
echo [1] 更改固定磁盘的图标
echo [2] 更改可移动磁盘的图标
echo [3] 更改指定磁盘的图标
echo [4] 恢复指定磁盘的图标
echo [0] 退出
echo.
set /p choice= 请选择(1/2/3/4/0):
if "%choice%"=="1" goto menudisk
if "%choice%"=="2" goto menumove
if "%choice%"=="3" goto menuadd
if "%choice%"=="4" goto menudel
if "%choice%"=="0" goto end
goto menu

:menudisk
cls
echo 正在更改固定磁盘的图标，请稍后...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
fsutil fsinfo drivetype %%a:|find /i "固定" >nul && (
copy autorun.ico %%a:\ >nul 2>nul
copy autorun.inf %%a:\ >nul 2>nul
attrib +r +s +h %%a:\autorun.ico >nul 2>nul
attrib +r +s +h %%a:\autorun.inf >nul 2>nul
))>nul 2>nul
cls
echo 更改完毕，按任意键返回... &pause>nul
goto menu


:menumove
cls
echo 正在更改可移动磁盘的图标，请稍后...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
fsutil fsinfo drivetype %%a:|find /i "移动" >nul && (
copy autorun.ico %%a:\ >nul 2>nul
copy autorun.inf %%a:\ >nul 2>nul
attrib +r +s +h %%a:\autorun.ico >nul 2>nul
attrib +r +s +h %%a:\autorun.inf >nul 2>nul
))>nul 2>nul
cls
echo 更改完毕，按任意键返回... &pause>nul
goto menu

:menuadd
cls
set /p disk= 请输入需要更改图标的盘符（可重复，不含引号，比如C D E F）：
for %%a in (%disk%) do (
copy autorun.ico %%a:\ >nul 2>nul
copy autorun.inf %%a:\ >nul 2>nul
attrib +r +s +h %%a:\autorun.ico >nul 2>nul
attrib +r +s +h %%a:\autorun.inf >nul 2>nul
)>nul 2>nul
cls
echo 更改完毕，按任意键返回... &pause>nul
goto menu

:menudel
cls
set /p disk= 请输入需要恢复图标的盘符（可重复，不含引号，比如C D E F）：
for %%a in (%disk%) do (
del /a:s /f %%a:\autorun.ico >nul 2>nul
del /a:s /f %%a:\autorun.inf >nul 2>nul
)>nul 2>nul
cls
echo 更改完毕，按任意键返回... &pause>nul
goto menu

:end
cls
echo -----------------------------------------------------
echo 操作完毕,谢谢您的使用!
echo.
echo           by LitteJack
echo           qq:279020803
echo.
echo 按任意键退出...
echo -----------------------------------------------------
pause>nul

保存成ADDico.bat。
将更改的autorun.inf文件和选择合适的ico图标文件复制到此文件夹（注意ico文件应跟autorun.inf中的icon=后的内容保持一致），然后就可以执行ADDico.bat来更改系统盘符的图标了。

如果嫌麻烦本人打包，只要将选择的图标改成autorun.ico覆盖到解压目录里，双击执行ADDico.bat。

评论