APPEND PROCEDURES 命令

将文本文件中的存储过程追加到当前数据库中。
APPEND PROCEDURES FROM FileName   [AS nCodePage] [OVERWRITE]
参数
FileName
指定文本文件，函数将追加其中的存储过程。

AS nCodePage
指定要追加其存储过程的文本文件所在的代码页。Visual FoxPro 在复制文本文件的内容时，自动将文本文件的内容转换成指定的代码页。

如果指定的 cCodePage 值无效，Visual FoxPro 将产生错误信息。可以使用 GETCP() 函数显示“代码页”对话框，并从中指定文本文件的代码页，此文本文件包含要追加的存储过程。

如果忽略 AS nCodePage，Visual FoxPro 将复制文本文件的内容，并自动将文本文件内容转化成 Visual FoxPro 的当前代码页。您可以用 CPCURRENT() 函数设置 Visual FoxPro 的当前代码页。

如果 nCodePage 值为零，Visual FoxPro 将假定文本文件的代码页与当前数据库的代码页相同，不进行代码页转换。

OVERWRITE
指定用文本文件中的过程改写数据库中的当前存储过程。如果忽略参数 OVERWRITE，将不改写数据库中的当前存储过程，文本文件中的存储过程追加到当前存储过程中。

备注
APPEND PROCEDURES 不能用于分发的可执行程序中。如果你的程序使用该命令, 将产生错误, "此功能不可用"。
使用 append procedures 命令，可以用编程方式修改数据库中的存储过程。运行 APPEND PROCEDURES 时，数据库必须是打开的，并且为当前数据库，否则 Visual FoxPro 将产生错误信息。
注意   要面查看或存储过程, 使用数据库设计器。

示例
下面的示例先打开数据库 testdata，然后创建一个包含单个备注字段的临时表 mytable，用 replace 命令把存储过程 myprocedure 存入备注字段中。接着使用 copy memo 命令创建包含备注字段内容的临时文本文件 mytemp.txt。
使用 append procedures 命令将临时文本文件中的存储过程追加到数据库中。使用 display procedures 命令显示数据库中的过程，然后删除临时表和文本文件。

CLOSE DATABASES
* 打开 testdata 数据库
OPEN DATABASE (HOME(2) + 'Data\testdata')

* 用名为 mProcedure 的备注字段创建一个自由, 临时表
CREATE TABLE mytable FREE (mProcedure M)
APPEND BLANK          && 添加一个空记录到 mytable

* 添加 PROCEDURE 命令, 名字和回车换行到
* 备注字段
REPLACE mProcedure WITH "PROCEDURE MyProcedure" + CHR(13) + CHR(10)

* 复制备注字段内容到临时文件
COPY MEMO mProcedure TO mytemp.txt
USE             && 关闭临时表

APPEND PROCEDURES FROM mytemp.txt   && 复制 PROCEDURE 到数据库
CLEAR

* 显示与当前数据库相关的过程
DISPLAY PROCEDURES
DELETE FILE mytable.dbf     && 删除临时表
DELETE FILE mytable.fpt     && 删除临时表备注字段
DELETE FILE mytemp.txt      && 删除临时文本文件

评论