VFP有很多命令，从今天开始，我会逐渐把这些命令都发出来，有兴趣的朋友可以看一下。这些都是VFP 8.0的帮助文件里面的，有想要VFP8.0帮助文件的朋友，可以联系我。命令以开头字母进行分类，今天先发以A开头的命令。

1.  ACTIVATE MENU 命令

ACTIVATE MENU 命令
显示并激活一个菜单栏。
ACTIVATE MENU MenuBarName   [NOWAIT]   [PAD MenuTitleName]
参数
MenuBarName
        指定要激活的菜单栏的名称。
NOWAIT
        指定在程序执行时，不等待用户在已激活菜单栏中选择菜单或按 ESC 键，而是继续执行程序。发出 DEACTIVATE MENU 命令后，如果菜单是用 NOWAIT 选项激活的，则程序的执行不返回到 ACTIVATEMENU
命令的下一行命令。 
        PAD MenuTitleName
指定一个菜单标题名，当激活菜单栏时，选中此菜单标题名。如果不指定菜单标题名，菜单栏激活后，默认激活第一个菜单标题名。
备注
        该命令显示并且激活 MenuBarName 指定的菜单栏，需要结合 DEFINE MENU 和 DEFINE PAD 命令使用。
注意   当应用程序中包含 Visual FoxPro 系统菜单栏 (_MSYSMENU) 时，不需激活此菜单，而是执行 SET SYSMENU AUTOMATIC 命令。
示例
        下面的示例用 ACTIVATE MENU 命令显示并激活一个用户定义的菜单系统。当前系统菜单栏先用 set sysmenu save 命令保存在内存中，然后用 set sysmenu to 命令删除所有系统菜单标题。
        用 define pad 命令创建两个菜单标题，并且用 define popup 为每个菜单标题创建下拉式菜单，然后用 define bar 命令在每个菜单上创建菜单项。当选中某个菜单标题后，on pad 命令使用 activate popup 子句激活相应菜单。ACTIVATE MENU 命令显示并激活这个选中的菜单栏。

        选择菜单中的某菜单项后，开始执行 choice 过程，choice 过程显示了选择的菜单项名和包含此项的菜单名。
*** 该程序名为 ACTIMENU.PRG ***
CLEAR
SET SYSMENU SAVE
SET SYSMENU TO
ON Key Label ESC KEYBOARD CHR(13)
DEFINE MENU example BAR AT LINE 1
DEFINE PAD convpad OF example PROMPT '\<Conversions' Color Scheme 3 ;
   KEY ALT+C, ''
DEFINE PAD cardpad OF example PROMPT 'Card \<Info' Color Scheme 3 ;
   KEY ALT+I, ''
ON PAD convpad OF example ACTIVATE POPUP conversion
ON PAD cardpad OF example ACTIVATE POPUP cardinfo
DEFINE POPUP conversion MARGIN RELATIVE Color Scheme 4
DEFINE BAR 1 OF conversion PROMPT 'Ar\<ea' ;
   KEY CTRL+E, '^E'
DEFINE BAR 2 OF conversion PROMPT '\<Length' ;
   KEY CTRL+L, '^L'
DEFINE BAR 3 OF conversion PROMPT 'Ma\<ss' ;
   KEY CTRL+S, '^S'
DEFINE BAR 4 OF conversion PROMPT 'Spee\<d' ;
   KEY CTRL+D, '^D'
DEFINE BAR 5 OF conversion PROMPT '\<Temperature' ;
   KEY CTRL+T, '^T'
DEFINE BAR 6 OF conversion PROMPT 'T\<ime' ;
   KEY CTRL+I, '^I'
DEFINE BAR 7 OF conversion PROMPT 'Volu\<me' ;
   KEY CTRL+M, '^M'
ON SELECTION POPUP conversion DO choice IN actimenu;
   WITH PROMPT(), POPUP()
DEFINE POPUP cardinfo MARGIN RELATIVE Color Scheme 4
DEFINE BAR 1 OF cardinfo PROMPT '\<View Charges' ;
   KEY ALT+V, ''
DEFINE BAR 2 OF cardinfo PROMPT 'View \<Payments' ;
   KEY ALT+P, ''
DEFINE BAR 3 OF cardinfo PROMPT 'Vie\<w Users' ;
   KEY ALT+W, ''
DEFINE BAR 4 OF cardinfo PROMPT '\-'
DEFINE BAR 5 OF cardinfo PROMPT '\<Charges ' ;
   KEY ALT+C, ''
ON SELECTION POPUP cardinfo;
   DO choice IN actimenu WITH PROMPT(), POPUP()

ACTIVATE MENU example
DEACTIVATE MENU example
RELEASE MENU example EXTENDED
SET SYSMENU TO DEFAULT
ON Key Label ESC
PROCEDURE choice
PARAMETERS mprompt, mpopup
WAIT WINDOW 'You chose ' + mprompt + ' from popup ' + mpopup NOWAIT

评论